ECHO OFF
REM  PROCEDURE CONVBOX
REM
REM  This procedure converts box characters to dashs and vertical bars
REM
REM  The parameters are:
REM
REM  %1 = Input file name
REM  %2 = Output file name
REM
IF "%1"=="" GOTO HELP
CLS
ECHO IMPS Version 3.1
ECHO ÿ
ECHO Procedure:  CONVBOX %1 %2
ECHO ÿ
IF NOT EXIST %1 GOTO NOFILE
ECHO     Input file:     %1
IF "%2"=="" GOTO MISSING2
IF NOT EXIST %2 GOTO OK2
IF %2==%1 GOTO SAME
ECHO     Output file:    %2  --  Already exists!
IMPSUTIL/R
IF ERRORLEVEL 1 GOTO XIT
ERASE %2
GOTO CONT
:OK2
ECHO     Output file:    %2
:CONT
ECHO ÿ
IMPSUTIL/B
IMPSBOX %1 %2
IMPSUTIL/E
IF ERRORLEVEL 200 GOTO ABORT
ECHO ÿ
ECHO Completed!
GOTO XIT
:HELP
CLS
ECHO      ....................................................................
ECHO      :                                                                  :
ECHO      :                            CONVBOX                               :
ECHO      :                            -------                               :
ECHO      :                                                                  :
ECHO      :      This procedure converts the box draw characters in a        :
ECHO      :      text file to dashes and vertical bars.                      :
ECHO      :                                                                  :
ECHO      :               CONVBOX   in-file   out-file                       :
ECHO      :                                                                  :
ECHO      :                                                                  :
ECHO      :               in-file   -  Input text file                       :
ECHO      :               out-file  -  Converted text file                   :
ECHO      :..................................................................:
GOTO XIT
:ABORT
ERASE %2
ECHO ÿ
ECHO Procedure Aborted  --  File error!
ECHO ÿ
ECHO     Data file %2 is not created!
GOTO XIT
:NOFILE
ECHO     Input file:     %1  --  Not found!
IF "%2"=="" GOTO MISSING2
IF %2==%1 GOTO SAME
ECHO     Output file:    %2
GOTO XIT
:MISSING2
ECHO     Output file:    ?  --  Missing!
GOTO XIT
:SAME
ECHO     Output file:    %2  --  Cannot be same as input file!
:XIT
ECHO ÿ